VB中创建超长时间计时器对象

摘　要：本文介绍在VB程序中用Timer控件创建一个超长时间的计时器对象，将其编译成ActiveX DLL部件，利用代码的可重用性，在其它应用程序中调用。
关键词：Vb  计时器  对象

VB系统中提供了固有计时器Timer控件，通过给计时器控件的Interval属性设置不同的数值，就可以控制计时器运行的时间间隔，但该属性是一个双字节的整型变量，最大值只能设置为65535，即只有65535毫秒,约一分钟多一点，在需要长时间计时时，该控件就无能为力了。本文给出用Timer控件创建一个超长时间的计时器对象，并将其编译成ActiveX DLL部件，供其它应用程序调用，可实现最大限度地利用代码的可重用性。下面给出这个超长计时器对象的编程设计过程，供读者参考选用。

1．编写程序
启动VB，新建一个ActiveX DLL工程，将工程命名为NewTimer，将类模块名Class1改名为LongTimer。在工程中添加一个窗体Form1，在窗体上加入一个Timer计时器控件Timer1。打开LongTimer类模块，加入如下程序代码：
Option Explicit
Public Event Tick()    '声明事件
Private nz As Integer
Private cs As Integer
Private m_Form As Form1
Private WithEvents m_Timer As Timer  '声明对象类变量

'返回Enable属性值
Public Property Get Enabled() As Boolean
  Enabled = m_Timer.Enabled
End Property

'设置Enable属性值
Public Property Let Enabled(ByVal vNewValue As Boolean)
    m_Timer.Enabled = vNewValue
End Property

'返回Interval属性值
Public Property Get Interval() As Long
  Interval = m_Timer.Interval
End Property

'设置Interval属性值
Public Property Let Interval(ByVal vNewValue As Long)
  cs = 0
  nz = vNewValue \ 65536 + 1
  m_Timer.Interval = vNewValue \ nz
End Property

'类初始化事件
Private Sub CLASS_Initialize()
  Set m_Form = New Form1
  Load m_Form
  Set m_Timer = m_Form.Timer1
End Sub

'类终止事件
Private Sub CLASS_Terminate()
  Unload m_Form
  Set m_Timer = Nothing
End Sub

'产生Tick事件
Private Sub m_Timer_Timer()
  cs = cs + 1
  If cs >= nz Then
     RaiseEvent Tick
     cs = 0
  End If
End Sub
窗体Form1只用来作计时器Timer1的载体，不用于显示。

2．测试NewTimer.DLL
对ActiveX DLL部件进行测试，与标准的EXE程序一样，可分为单步运行或全运行。在写完所有程序代码后，建议用户先用Ctrl+F5进行全编译执行，发现检查NewTimer程序的语法错误。也可建立一个测试工程与NewTimer链接进行测试，针对由NewTimer类模块提供的每个属性和事件，添加测试代码来测试它们的属性和方法。按F8，进入单步运行状态，逐个语句察看对NewTimer类模块的调用情况。

3．编译NewTimer.DLL
完成测试，排除所有错误后，从“文件（F）”菜单中选择“生成NewTimer.dll（K)”命令，编译生成NewTimer.dll文件。编译成功后NewTimer.dll文件将自动注册到Windows注册表中，

《VB中创建超长时间计时器对象》